Delta Function Potential

After the free particle, the most elementary example of a one-dimensional time-independent Schrödinger equation is conceptually that of a particle in a delta function potential: -(1/2)ψ''(x)+α δ(x)ψ(x)=E ψ(x) (in units with ℏ=m=1). For an attractive potential, with α<0, there is exactly one bound state, with (Subscript[E, 0])=-((α^2)/2) and (Subscript[ψ, 0])(x)=|α|(e^(-|α x|)). Note that (d/( d x))|x|=sign(x) and ((d^2)/( d (x^2)))|x|=2 δ(x). Since the delta function has dimensions of 1/|x|, this solution is considered the one-dimensional analog of a hydrogen-like atom. The bound state, in fact, resembles a cross section of a 1s orbital (e^(-Z r)).

For E>0, free particles are scattered by a delta function potential. The positive-energy solutions can be written (Subscript[ψ, k]^±)(x)=(1/(Sqrt[2π]))((e^(±i k x))+(α/(i k-α))(e^(i k |x|))), with E=(k^2)/2. The amplitudes of the transmitted and reflected waves are accordingly given by ((k^2)/((k^2)+(α^2))) and ((α^2)/((k^2)+(α^2))), respectively. Note that these are the same for attractive and repulsive delta funtion potentials, independent of the sign of α.

For continuum states, the graphic shows a wave incident from the left. The transmitted wave is shown on the right in blue and the reflected wave, on the left in red, with opacities indicating relative wave amplitudes.

ψ0[α_,x_]:=-α (E^(α Abs[x]))Boole[α<0];
ψi[α_,k_,x_]:=(1/(Sqrt[2π]))Cos[k x];
ψt[α,k_,x_]:=(1/(Sqrt[2π]))(((k^2) Cos[k x]+k α Sin[k x])/((k^2)+(α^2)));
ψr[α_,k_,x_]:=-(1/(Sqrt[2π]))(((α^2) Cos[k x]+k α Sin[k x])/((k^2)+(α^2)));
g[0,α_,k_]:=Plot[ψ0[α,x],{x,-4,4},PlotStyle->Directive[{Thick,Opacity[Boole[α<0]],RGBColor[.25,.43,.82]}],
PlotRange->{-.5,1.5},Frame->True,FrameLabel->{Style[x,18],Style[Row[{Subscript[ψ,0],"(",x,")"}],18]}];
gi[α_,k_]:=Plot[{ψi[α,k,x],ψr[α,k,x]},{x,-3π,0},PlotStyle->{Directive[{Thick,RGBColor[.25,.43,.82]}],Directive[{Thick,Opacity[((α^2)/((k^2)+(α^2)))],RGBColor[.49,0,0]}]},
Frame->True,FrameLabel->{Style[x,18],Style[Row[{Re," ",Subscript[ψ,Style["k",Italic]],"(",x,")"}],18]}];
gt[α_,k_]:=Plot[ψt[α,k,x],{x,0,3π},PlotStyle->Directive[{Thick,Opacity[((k^2)/((k^2)+(α^2)))],RGBColor[.25,.43,.82]}],
Frame->True];
g[1,α_,k_]:=Show[gi[α,k],gt[α,k],PlotRange->{{-3π,3π},{-1.5/(Sqrt[2π]),1.5/(Sqrt[2π])}}];
Manipulate[
Show[g[b,α,k],
ImageSize->{575,350}],
{{b,1," "},{0->"bound state",1->"continuum"},Setter},
{{α,0,"α"},-1,1,.1,Appearance->"Labeled"},{{k,1,Style["k",Italic]},.5,2,Appearance->"Labeled",Enabled->Dynamic[b==1]},
TrackedSymbols:>{b,α,k},
SaveDefinitions->True]